Previous Up Next
Retour à la page personnelle de Bernard Parisse.

Chapitre 12  Exemples de courbes en polaire

On donne ici les équations en polaire de différentes courbes.

12.1  La droite

r= 1/acos(θ)+bsin(θ)

12.2  Le cercle passant par O

r=acos(θ)+bsin(θ)

12.3  Conique

12.3.1  Conique de foyer O

r=p/1+ecos(θ)

12.3.2  Conique générale

r=1/a+bcos(θ)+csin(θ)

12.4  Conchoïde de courbes

12.4.1  Définition

On appelle conchoïde d’une courbe (C) par rapport à un point O le lieu (Γ) des points M et N que l’on obtient en portant sur la droite OP : PM=−PN=a lorsque P décrit la courbe C et que a a une valeur constante.
Si l’équation polaire de C est r=f(θ), celle de (Γ) est : r=f(θ)± a.
Remarque
Si f(θ−π)=−f(θ) alors le double signe est inutile. En effet un point K de coordonnées polaires r,θ est aussi et le point K1 de coordonnées polaires −r,θ+π.
Si on considère :
le point M de coordonnées polaires :
f(θ)+a,θ et
θ1=θ+π On a :
f(θ)+a=f1−π)+a=−f1)+a=−(f1)−a) le point M de coordonnées polaires f(θ)+a,θ est donc identique au point de coordonnées polaires :
−(f1)−a,θ) qui est le point N de coordonnées polaires f1)−a1.

12.4.2  Conchoïde de droite ou conchoïde de Nicomède

Soient une droite d, un point O non situé sur d et un nombre réel a.
La conchoïde de Nicomède est le lieu (Γ) des points M et N que l’on obtient en portant sur la droite OP : PM=−PN=a lorsque P décrit la droite d et que a a une valeur constante.
Soit h la distance de O à la droite d.
La conchoïde de Nicomède a comme équation :

r=h/cos(θ)+a

Le double signe est inutile car cos(θ−π)=−cos(θ).
Avec Xcas
On tape :

O:=point(0,0);
d:=droite(x=3);
a:=element(1..5);
plotpolar(3/cos(t)+a,t,affichage=rouge)

On a choisit h=3. On peut ainsi faire varier a et voir les 3 cas :
h<a, h=a, h>a. On peut trouver l’équation cartésienne :
r=rh/x+a donc
rrh/x=r(xh)/x=a donc

(x2+y2)(xh)2a2x2=0

c’est donc une quartique. On peut faire une animation et voir la construction de la courbe quand P se déplace sur la droite d.
On ouvre un écran de géométrie 2D et on tape (on a choisit h=3 et a entre 1 et 5) pour faire une animation (ne pas oublier de mettre animate à 0.5 à l’aide du bouton cfg :

O:=point(0,0);
d:=droite(x=3):;d;
supposons(a=[4.3,-5.0,5.0,0.0]);
plotpolar(3/cos(t)+a,t,affichage=rouge);
T(a,u,x):=(3/(-a*sin(u)*cos(u)^2)-cos(u)/sin(u))*x+
(a+3/cos(u))^2/(a*sin(u));
animation(seq('droite(y=tan(u)*x)',u,-10,10,0.1));
animation(seq('P:=point(3+i*tan(u)*3)',u,-10,10,0.1));
animation(seq('M:=point((3/cos(u)+a)*exp(i*u))',u,-10,10,0.1));
animation(seq('droite(y=T(a,u,x),affichage=vert)',u,-10,10,0.1));

On obtient :
La conchoïde de Nicomède (en rouge) :

On suppose maintenant que des rayons parallèles à l’axe des y se réfléchissent sur la deuxième nappe (lorsque −π/2<θ<π/2).
Pour avoir la trace des rayons réfléchis, on tape :

O:=point(0,0);
d:=droite(x=3):;d;
supposons(a=[4.3,-5.0,5.0,0.0]);
plotpolar(3/cos(t)+a,t,affichage=rouge);
T(a,u,x):=(3/(-a*sin(u)*cos(u)^2)-cos(u)/sin(u))*x+
(a+3/cos(u))^2/(a*sin(u));
N:=unapply(equal2list(equation(perpendiculaire(
             M,droite(y=T(a,u,x)))))[1],[a,u,x]);
//N(a,u,x):=(a*sin(u)*cos(u)^2)/(3+a*cos(u)^3)*x+
//(9*tan(u)+3*a*sin(u))/(3+a*cos(u)^3);
supposons(u:=[1.2,(-pi)/2,pi/2,0.05]);
M:=point((3/cos(u)+a)*exp(i*u));
dd:=symetrie(droite(y=N(a,u,x)),
    demi_droite(M,point(i*(3/cos(u)+a)*sin(u)))):;
trace(dd);

On obtient quand on fait bouger le curseur u pour avoir la trace des rayons réfléchis :

Les rayons réfléchis sur une conchoïde de Nicomède

12.4.3  Conchoïde de cercle

On construit ainsi le limaçon de Pascal.
Soit un cercle C de rayon R, un point O situé sur C et un nombre réel a. Le limaçon de Pascal est le lieu (Γ) des points M et N que l’on obtient en portant sur la droite OP : PM=−PN=a lorsque P décrit le cercle C et que a a une valeur constante.

Une conchoïde de cercle a comme équation :

r=2Rcos(θ)+a

Le double signe est inutile car cos(θ−π)=−cos(θ).
Avec Xcas
On tape :

O:=point(0,0);
C:=cercle(3,3);
a:=element(1..5);
plotpolar(6*cos(t)+a,t,affichage=rouge);

On a choisit R=3. On peut ainsi faire varier a et voir les 3 cas :
2R<a, 2R=a, 2R>a.
Lorsque 2R=a on a r=2R(cos(θ)+1)=a(cos(θ)+1) c’est donc une cardioïde.
On peut faire une animation et voir et les points M, N et la construction de la courbe quand P se déplace sur le cercle C.
On tape :

O:=point(0,0);
C:=cercle(3,3);
a:=element(1..5);
plotpolar(6*cos(t)+a,t,affichage=rouge);
animation(seq('droite(y=tan(u)*x)',u=-10..10));
animation(seq('P:=point(6*cos(u)*exp(i*u))',u,-10,10));
animation(seq('M:=point((6*cos(u)+a)*exp(i*u))',u,-10,10));
animation(seq('N:=point((6*cos(u)-a)*exp(i*u))',u,-10,10));

12.5  Cissoïde droite et strophoïde droite

12.5.1  Cissoïde droite

Soient une droite d, un point O non situé sur d et H la projection orthogonale de O sur d. Soit h=OH la distance de O à la droite d et C le cercle de diamètre OH.
Soit P un point de d et N l’intersection de OP avec C. Lorsque P décrit la droite d, le lieu de M, obtenu en portant sur OP, OM=NP est une cissoïde droite.
Si O est l’origine, OH l’axe des x et t l’angle de OP avec Ox, on a :
P=point(h/cos(t)*exp(i*t)), N=point(h*cos(t)*exp(i*t)), OM=NP=h*exp(i*t)*(1/cos(t)−cos(t))=h*exp(i*t)*(1−cos(t)2)/cos(t)=x+i*y=r*exp(i*t) Donc :
x=h*sin(t)2 et y=h*tan(t)*sin(t)2 et
r=h*sin(t)2/cos(t)
donc l’équation polaire de la cissoïde droite est :
r=h*sin(t)2/cos(t).
Avec Xcas
On tape :

O:=point(0,0);
h:=element(0..6);
d:=droite(x=h);
cercle(0,point(h));
plotpolar(h*sin(t)^2/cos(t),t,affichage=rouge);

Cette courbe ressemble à un morceau de conchoïde de droite lorsque a<h.

12.5.2  Strophoïde droite

Soient une droite d, un point O non situé sur d et H la projection orthogonale de O sur d. Soit h=OH la distance de O à la droite d .
Soit P un point de d. Lorsque P décrit la droite d, le point M de la droite OP tel que PM=overlineHP est une strophoïde droite.
Si O est l’origine, OH l’axe des x, et t l’angle de OP avec Ox, on a:
P=point(h/cos(t)*exp(i*t))=point(h*(1+i*tan(t)))
|OP|=h/cos(t)
H=point(h)
PH=h*tan(t)
On a :
OM=OP+overlineHP
donc :
OM=OP+OP*cos(t)*tan(t))=OP*(1+sin(t))
Donc on a :
OM=h*(1+sin(t))/cos(t)*exp(i*t))=r*exp(i*t)
donc l’équation polaire de la strophoïde droite est :
r=h*(1+sin(t))/cos(t).
Cette courbe ressemble à un morceau de conchoïde de droite lorsque a>h. Remarque
Si on prend l’origine en H on a comme équation polaire:
r=−h*cos(2*t))/cos(t).
Avec Xcas
On peut faire une animation et voir la construction de la courbe quand P se déplace sur la droite d.
On tape :

O:=point(0,0);
h:=element(1..5);
d:=droite(x=h);
plotpolar(h*(1+sin(t))/cos(t),t,affichage=rouge);
animation(seq('droite(y=tan(u)*x)',u,-10,10,0.5));
animation(seq('P:=point(h+i*tan(u)*h)',u,-10,10,0.5));
animation(seq('M:=point(h*(1+sin(u))/cos(u))*exp(i*u)',u,-10,10,0.5));

12.6  Ovale de Cassini

12.6.1  Définition

Étant donnés deux points F1 et F2 et un nombre réel k, le lieu de M de coordonnées (x;y) tel que MF1*MF2=k2 est une ovale de Cassini.
Si O est le milieu de F1F2 et OF1=c, on a :
MF12=(x+c)2+y2 et MF22=(xc)2+y2 donc
MF12*MF22=((x+c)2+y2)*((xc)2+y2)=
c4−2*c2*x2+2*c2*y2+(x2+y2)2 Alors le lieu de M a pour équation : (x2+y2)2−2*c2*(x2y2)=k4c4
ou encore
(x2+y2+c2)2=4*c2*x2+k4

12.6.2  Lemniscate de Bernoulli

Une lemniscate de Bernoulli est une ovale de Cassini avec :
k=OF1=c.
Posons a=c*√2.
Donc c’est le lieu de M tel que : MF1*MF2=OF12 et on a :
(x2+y2)2=a2*(x2y2)
si x=r*cos(t) et y=r*sin(t) on a : r4=a2*r2*(cos(t)2−sin(t)2)=a2*r2*cos(2*t) donc
r2=a2*cos(2*t)
L’équation polaire d’une lemniscate de Bernouilli est :
ra*√cos(2*t)

Avec Xcas
On tape :

O:=point(0,0);
a:=element(1..5);
F1:=point(-a*sqrt(2)/2,0);
F2:=point(a*sqrt(2)/2,0);
plotpolar(a*sqrt(cos(2*t)),t=0..2*pi);

12.7  Limaçon de Pascal

L’équation cartésienne du limaçon de Pascal est :
(x2+y2a*x)2=b2*(x2+y2)
L’équation polaire du limaçon de Pascal est :
r=a*cos(t)+b Avec Xcas
On tape :

a:=element(1..5);
b:=element(0..5);
plotpolar(a*cos(t)+b,t=-10..10);

12.8  Cardioïde

12.8.1  Équations d’une cardioïde

Soit la cardioïde de paramètre a ayant sont point de rebroussement en O et passant par le point A=2a. Son équation cartésienne est :
(x2+y2)2−2*a*x*(x2+y2)−a2*y2
Son équation paramétrique est :
x=a*(1+cos(t))*cos(t)=(2*cos(t)+cos(2t)+1)*a/2,
y=a*(1+cos(t))*sin(t)=(2*sin(t)+sin(2t)+1)*a/2. Son équation polaire est :
r=a*(1+cos(t)).

Une cardioïde est le lieu d’un point M situé sur un cercle de rayon a/2 qui roule sans glisser sur un cercle fixe de même rayon et de centre a/2.
On tape :

assume(t=[1.570796325,0,2*pi]);
cercle(0,1);
cercle(2*exp(i*t),1);
A:=point(2*exp(i*t)-exp(2*i*t));
plotparam(affixe(A),t)
//lieu(A,t);

On obtient une cardioïde de paramètre a=2 ayant sont point de rebroussement en 1 et passant par le point A=−3.
On peut se reporter à la section 11.2.1 pour voir les animations sur les épicycloïdes.

12.8.2  La longueur d’une cardioïde

La cardioïde a pour équation polaire r=a(cos(t)+1). On peut calculer la longueur d’une cardioïde.
On a :
ds2=dr2+r2dt2
On tape :
normal(diff(a*(cos(t)+1),t)^2+(a*(cos(t)+1))^2)
On obtient :
a^2*cos(t)^2+2*a^2*cos(t)+a^2*sin(t)^2+a^2
On tape :
trigcos(halftan(trigcos(a^2*cos(t)^2+2*a^2*cos(t)+a^2*sin(t)^2+a^2)))
On obtient :
4*a^2*cos(t/2)^2
On tape :
2*int(2*a*cos(t/2),t,0,pi)
On obtient :
2*4*a
La longueur de la cardioïde d’équation r=a(cos(θ)+1) est donc 8*a.

12.9  La cycloïde

t:=element(0 .. 7,0);
cercle(t+i,1);
A:=point(t+i-i*exp(-(i)*t));
lieu(A,t);

12.10  La Néphroïde

t:=element(0 .. 7,0);
cercle(0,2);
cercle(3*exp(i*t),1);
A:=point(3*exp(i*t)-exp(3*i*t))
lieu(A,t);

12.11  L’hypocycloïde à 3 rebroussements

t:=element(0 .. 7,0);
cercle(0,3);
cercle(2exp(i*t),1);
A:=point(2*exp(i*t)+exp(-2*i*t));
lieu(A,t);

12.12  L’astroïde

t:=element(0 .. 7,0);
cercle(0,2);
cercle(3/2*exp(i*t),1/2);
A:=point(3/2*exp(i*t)+1/2*exp(-3*i*t));
lieu(A,t);

12.13  Les rosaces

Ce sont les courbes qui ont comme équation polaire r=a*sin(m*t) et l’origine est le centre de la rosace.
Lorsque m est rationnel ces courbes se referment et lorsque m est irrationnel ces courbes sont formées de boucles qui se déduisent l’une de l’autre par des rotations de centre O et d’angle π/m

12.13.1  Rosace à 4 boucles

Cette rosace a pour équation :
r=a*sin(2*t)
En coordonnées cartésienne son équation est :
(x2+y2)3=4a2x2y2

12.13.2  Une rosace à 10 boucles

Cette rosace a pour équation :
r=a*sin(5/2*t)

12.13.3  Une rosace à une infinité de boucles

On trace la rosace qui a pour équation :
r=a*sin(sqrt(2)*t)
Avec Xcas
On tape :

a:=element(1..5);
m:=element(1..5);
plotpolar(a*sin(m*t),t=-10..10);

12.14  Les courbes de Moritz

Ce sont les courbes en forme de fleurs qui ont comme équation polaire r=a*cos(m*t)+b et l’origine est le centre de la fleur.
Lorsque m est rationnel ces courbes se referment et lorsque m est irrationnel ces courbes sont formées de boucles qui se déduisent l’une de l’autre par des rotations de centre O et d’angle π/m

12.14.1  Les trèfles

Le trèfle simple a pour équation :
r=cos(3*t)
Le trèfle général a pour équation :
r=cos(3*t)+b
Essayez r=cos(3*t)+1/3

12.14.2  Les fleurs à 14 pétales

Les fleurs à 14 pétales ont par exemple pour équation :
r=cos(14*t), r=cos(7/2*t) ou r=cos(7/4*t) Et plus généralement, les fleurs d’équation :
r=cos(7/p*t)+b

12.14.3  Les différents cas

On essayera :
m=7,b=3
m=3/2,b=1/4
m=5/2,b=3
m=7/2,b=0
m=1/3,b=1/9
m=5/4,b=1/3
m=7/4,b=0
m=9/4,b=7/3
etc...
Avec Xcas
On tape :

a:=element(1..5);
b:=element(0..5);
m:=element(1..5);
plotpolar(a*sin(m*t),t=-10..10);

12.15  Les spirales

12.15.1  La spirale d’Archimède

L’équation polaire de la spirale d’Archimède est :
r=a

12.15.2  La spirale hyperbolique

L’équation polaire de la spirale hyperbolique est :
r=a
C’est l’inverse de la spirale d’Archimède.

12.15.3  La spirale parabolique

L’équation polaire de la spirale parabolique est :
r=a ± √(2*a*p*θ))

12.15.4  La spirale logarithmique

L’équation polaire de la spirale logarithmique est :
r=a*exp(m*θ)

12.15.5  La spirale de Galilée

L’équation polaire de la spirale de Galilée est :
r=a*(1−m2)

12.15.6  La spirale de Fermat

L’équation polaire de la spirale de Fermat est :
ra*sqrt(θ)

12.15.7  La spirale de Poinsot

L’équation polaire de la spirale de Poinsot est :
r=a/cosh(m*θ)

12.15.8  Lituus

L’équation polaire du lituus est :
r=a/sqrt(θ)
Si M est un point de cette courbe, et si m est le point de l’axe des x tel que Om=OM, alors l’aire du secteur circulaire OmM est constante.

12.15.9  Courbe du spiral

L’équation polaire de la courbe du spiral est :
r=a/(1+m*exp(k*θ))

12.16  Les courbes de Lissajous

Les courbes de Lissajous ont comme équation paramétrique :
x(t)=acos( t)
y(t)=bsin( t+φ)
Avec Xcas
On tape :

k:=element(0 .. 4);
m:=element(0 .. 4);
p:=element(0..pi/2);
plotparam(3*cos(k*t)+i*2*sin(m*t+p),t);

On peut voir les différentes courbes en faisant varier m et p.
En particulier k=1 et m=1 puis on fait varier p, k=2 et m=3 puis on fait varier p etc...

Retour à la page personnelle de Bernard Parisse.
Previous Up Next